Anchored Variables
Volume Number: 1
Issue Number: 8
Column Tag: Programmer's Forum
"Modula-2 and Anchored Variables
By Tom Taylor, Software Engineer, Modula-2 Corp., Provo, Ut.
"Modula-2 and Anchored Variables
The programming language Modula-2 supports a little known but extremely
powerful feature called "anchored variables." Anchored variables allow one to specify
in the variable's declaration the absolute address of the variable and override the
compiler's allocation method. This feature was intended to allow access to device
registers on computers with memory mapped I/O (like on a PDP-11 where the
original Modula-2 compiler was developed). It also allows the Modula-2 programmer
on the Macintosh to access the Mac's operating system global variables very
conveniently and cleanly.
In this article, we will look at two examples of anchored variable usage. In the
first, we will try a small example to show that anchored variables really do work. In
the second example, we'll actually develop a useful module based on anchored variables.
These examples have been programed using MacModula-2 by Modula Corporation.
However, with minor changes to the programs (probably the import statements),
these programs should run using any Modula-2 system.
Anchored variables are "anchored" to a specific address by specifying that
address in brackets immediately following the variable name in a variable declaration
and before specifying the variable's type. For example:
VAR
FinderName [2E0h]
: ARRAY [0..16] OF CHAR;
This statement tells the compiler to allocate the variable FinderName starting at
hex location 2E0h. Location 2E0h just happens to contain a Mac style string with the
name of the current finder. The following program, will print out the name of the
currently installed finder:
MODULE PrintFinder;
FROM Terminal IMPORT
ClearScreen, Write,
Read, WriteLn, WriteString;
VAR
FinderName [2e0h] :
ARRAY [0..16] OF CHAR;
i : CARDINAL;
ch : CHAR;
BEGIN
ClearScreen;
WriteString("Current finder is: ");
FOR i := 1 TO ORD(FinderName[0]) DO
Write(FinderName[i]);
END;
WriteLn;
Read(ch);
END PrintFinder.
Volume Control Block Queue
This next example is slightly more useful. It demonstrates the use of anchored
variables in traversing the Volume Control Block queue and returning information
about any disk (or volume) visible on the desktop (inserted in a drive or ejected) at
the time your program was launched. This technique is used, for example, in the
MacModula-2 compiler and linker when they search for imported files. This feature
allows users of single drive Macs to build programs that are spred out over a number
of disks by having those disks visible on the desktop at the time the compiler or linker
is launched. The compiler or linker will search each disk found on the desktop by
traversing the VCB queue until the desired import file is found or the end of the queue
is reached.
The following example actually consists of three modules:
1) a Definition Module that defines the records, types, global variables, and
procedures that are available for use by any program.
2) An Implementation Module that contains the code for the procedures defined in the
Definition Module.
3) A simple Program Module that uses the procedures we have written and
demonstrates some of the information available from the Volume Control Blocks.
DEFINITION MODULE VolumeTracer;
FROM MacSystemTypes IMPORT LongCard, Ptr;
EXPORT QUALIFIED VCB, VolumesOnLine,
GetVolumeInfo;
TYPE
QElemPtr = POINTER TO VCB;
VCB = RECORD
qLink: QElemPtr;
(* next queue entry *)
qType: INTEGER;
(* not used *)
vcbFlags: INTEGER;
(* bit 15=1 if dirty *)
vcbSigWord: INTEGER;
(* always $D2D7 *)
vcbCrDate: LongCard;
(* date volume initialized *)
vcbLsBkUp: LongCard;
(* date of last backup *)
vcbAtrb: INTEGER;
(* volume attributes *)
vcbNmFls: INTEGER;
(* # of files in directory *)
vcbDirSt: INTEGER;
(* directory's first block *)
vcbBlLn: INTEGER;
(* length of file directory *)
vcbNmBlks: INTEGER;
(* # of allocation blocks *)
vcbAlBlkSiz: LongCard;
(* size of allocation blocks *)
vcbClpSiz: LongCard;
(* # of bytes to allocate *)
vcbAlBlSt: INTEGER;
(* first block in block map *)
vcbNxtFNum: LongCard;
(* next unused file number *)
vcbFreeBks: INTEGER;
(* number of unused blocks *)
vcbVN: ARRAY [0..27] OF CHAR;
(* vol name Str255 format *)
vcbDrvNum: INTEGER;
(* drive number *)
vcbDRefNum: INTEGER;
(* driver reference number *)
vcbFSID: INTEGER;
(* file system identifier *)
vcbVRefNum: INTEGER;
(* volume reference number *)
vcbMAdr: Ptr;
(* location of block map *)
vcbBufAdr: Ptr;
(* location of volume buffer *)
vcbMLen: INTEGER;
(* # of bytes in block map *)
vcbDirIndex: INTEGER;
(* used internally *)
vcbDirBlk: INTEGER;
(* used internally *)
END;
PROCEDURE VolumesOnLine(): CARDINAL;
(* Returns the maximum number of
volumes currently recognized by the
Mac operating system. *)
PROCEDURE GetVolumeInfo(VAR volume :
VCB; whichVol : CARDINAL);
(* Returns the current VCB block for
volume " whichVol" The variable
" whichVol" must be between 1 and
the result of the procedure of
"VolumesOnLine()". Otherwise,
the " volume" info is undefined. *)
END VolumeTracer.
IMPLEMENTATION MODULE VolumeTracer;
TYPE
QHdrPtr = POINTER TO QHdr;
QHdr = RECORD
qFlags : INTEGER;
(* queue flags *)
qHead : QElemPtr;
(* first queue entry *)
qTail : QElemPtr;
(* last queue entry *)
END;
VAR
VCBQHdr [0356h] : QHdr;
(* VCB queue header *)
PROCEDURE VolumesOnLine(): CARDINAL;
VAR
ptr : QElemPtr;
count : CARDINAL;
BEGIN
ptr := VCBQHdr.qHead;
count := 0;
WHILE ptr # NIL DO
INC(count);
ptr := ptr^.qLink;
END;
RETURN count;
END VolumesOnLine;
PROCEDURE GetVolumeInfo(VAR volume :
VCB; whichVol : CARDINAL);
VAR
ptr : QElemPtr;
count : CARDINAL;
BEGIN
ptr := VCBQHdr.qHead;
count := 0;
WHILE (ptr # NIL) AND
(count # whichVol) DO
INC(count);
IF count = whichVol THEN
volume := ptr^;
END;
ptr := ptr^.qLink;
END;
END GetVolumeInfo;
END VolumeTracer.
MODULE ListVolumes;
FROM VolumeTracer IMPORT
VCB, VolumesOnLine, GetVolumeInfo;
FROM InOut IMPORT WriteString, ClearScreen, WriteLn, WriteCard,
WriteInt, Write, Read;
VAR
i, maxVols : CARDINAL;
vcb : VCB;
ch : CHAR;
PROCEDURE PrintVolName;
VAR
i : CARDINAL;
BEGIN
FOR i := 1 TO ORD(vcb.vcbVN[0]) DO
Write(vcb.vcbVN[i]);
END;
WriteLn;
END PrintVolName;
BEGIN
ClearScreen;
WriteString
("Number of volumes on-line: ");
maxVols := VolumesOnLine();
WriteCard(maxVols,0);
WriteLn; WriteLn;
FOR i := 1 TO maxVols DO
GetVolumeInfo(vcb,i);
WriteString('Volume Name: ');
PrintVolName;
WriteString
('Number of files in volume: ');
WriteInt(vcb.vcbNmFls,0);
WriteLn;
WriteString('Drive Number: ');
WriteInt(vcb.vcbDrvNum,0);
WriteLn;
WriteLn;
END;
Read(ch);
END ListVolumes.
Figure 1. Typical VCB Queue
This is only one simple example of a typical use of anchored variables. Many
times, Inside Macintosh will mention some variable that can be accessed from
assembly language. The Window Manager, for example, mentions that putting a
WindowPtr in the variable GhostWindow, will cause that window to never be the front
window. In order to find the addresses of such variables, such as GhostWindow, one
need simply paw through ToolEqu.TXT or SysEqu.TXT. Both of these source files are
included with the MDS system by Apple. Not only have I used GhostWindow as an
anchored variable in my applications, I have also used anchored variables to access the
information set by the Finder when a program is launched.
By taking advantage of the power of anchored variables, you will be able to create
very readable programs that use some of the Mac's low-level features.
Referenced by (2):